sys/boot/i386/pxeldr/pxeldr.S

   1 /*
   2  * Copyright (c) 2000 John Baldwin
   3  * All rights reserved.
   4  *
   5  * Redistribution and use in source and binary forms are freely
   6  * permitted provided that the above copyright notice and this
   7  * paragraph and the following disclaimer are duplicated in all
   8  * such forms.
   9  *
  10  * This software is provided "AS IS" and without any express or
  11  * implied warranties, including, without limitation, the implied
  12  * warranties of merchantability and fitness for a particular
  13  * purpose.
  14  *
  15  * $FreeBSD$
  16  */
  17
  18 /*
  19  * This simple program is a preloader for the normal boot3 loader.  It is simply
  20  * prepended to the beginning of a fully built and btxld'd loader.  It then
  21  * copies the loader to the address boot2 normally loads it, emulates the
  22  * boot[12] environment (protected mode, a bootinfo struct, etc.), and then jumps
  23  * to the start of btxldr to start the boot process.  This method allows a stock
  24  * /boot/loader to be booted over the network via PXE w/o having to write a
  25  * separate PXE-aware client just to load the loader.
  26  */
  27
  28 #include <sys/reboot.h>
  29 #include <bootargs.h>
  30
  31 /*
  32  * Memory locations.
  33  */
  34                 .set MEM_PAGE_SIZE,0x1000       # memory page size, 4k
  35                 .set MEM_ARG,0x900              # Arguments at start
  36                 .set MEM_ARG_BTX,0xa100         # Where we move them to so the
  37                                                 #  BTX client can see them
  38                 .set MEM_ARG_SIZE,0x18          # Size of the arguments
  39                 .set MEM_BTX_ADDRESS,0x9000     # where BTX lives
  40                 .set MEM_BTX_ENTRY,0x9010       # where BTX starts to execute
  41                 .set MEM_BTX_OFFSET,MEM_PAGE_SIZE # offset of BTX in the loader
  42                 .set MEM_BTX_CLIENT,0xa000      # where BTX clients live
  43                 .set MEM_BIOS_KEYBOARD,0x496    # BDA byte with keyboard bit
  44 /*
  45  * a.out header fields
  46  */
  47                 .set AOUT_TEXT,0x04             # text segment size
  48                 .set AOUT_DATA,0x08             # data segment size
  49                 .set AOUT_BSS,0x0c              # zero'd BSS size
  50                 .set AOUT_SYMBOLS,0x10          # symbol table
  51                 .set AOUT_ENTRY,0x14            # entry point
  52                 .set AOUT_HEADER,MEM_PAGE_SIZE  # size of the a.out header
  53 /*
  54  * Segment selectors.
  55  */
  56                 .set SEL_SDATA,0x8              # Supervisor data
  57                 .set SEL_RDATA,0x10             # Real mode data
  58                 .set SEL_SCODE,0x18             # PM-32 code
  59                 .set SEL_SCODE16,0x20           # PM-16 code
  60 /*
  61  * BTX constants
  62  */
  63                 .set INT_SYS,0x30               # BTX syscall interrupt
  64 /*
  65  * Bit in MEM_BIOS_KEYBOARD that is set if an enhanced keyboard is present
  66  */
  67                 .set KEYBOARD_BIT,0x10
  68 /*
  69  * We expect to be loaded by the BIOS at 0x7c00 (standard boot loader entry
  70  * point)
  71  */
  72                 .code16
  73                 .globl start
  74                 .org 0x0, 0x0
  75 /*
  76  * BTX program loader for PXE network booting
  77  */
  78 start:          cld                             # string ops inc
  79                 xorw %ax, %ax                   # zero %ax
  80                 movw %ax, %ss                   # setup the
  81                 movw $start, %sp                #  stack
  82                 movw %es, %cx                   # save PXENV+ segment
  83                 movw %ax, %ds                   # setup the
  84                 movw %ax, %es                   #  data segments
  85                 andl $0xffff, %ecx              # clear upper words
  86                 andl $0xffff, %ebx              #  of %ebx and %ecx
  87                 shll $4, %ecx                   # calculate the offset of
  88                 addl %ebx, %ecx                 #  the PXENV+ struct and
  89                 pushl %ecx                      #  save it on the stack
  90                 movw $welcome_msg, %si          # %ds:(%si) -> welcome message
  91                 callw putstr                    # display the welcome message
  92 /*
  93  * Setup the arguments that the loader is expecting from boot[12]
  94  */
  95                 movw $bootinfo_msg, %si         # %ds:(%si) -> boot args message
  96                 callw putstr                    # display the message
  97                 movw $MEM_ARG, %bx              # %ds:(%bx) -> boot args
  98                 movw %bx, %di                   # %es:(%di) -> boot args
  99                 xorl %eax, %eax                 # zero %eax
 100                 movw $(MEM_ARG_SIZE/4), %cx     # Size of arguments in 32-bit
 101                                                 #  dwords
 102                 rep                             # Clear the arguments
 103                 stosl                           #  to zero
 104                 orb $KARGS_FLAGS_PXE, 0x8(%bx)  # kargs->bootflags |=
 105                                                 #  KARGS_FLAGS_PXE
 106                 popl 0xc(%bx)                   # kargs->pxeinfo = *PXENV+
 107 #ifdef ALWAYS_SERIAL
 108 /*
 109  * set the RBX_SERIAL bit in the howto byte.
 110  */
 111                 orl $RB_SERIAL, (%bx)           # enable serial console
 112 #endif
 113 #ifdef PROBE_KEYBOARD
 114 /*
 115  * Look at the BIOS data area to see if we have an enhanced keyboard.  If not,
 116  * set the RBX_DUAL and RBX_SERIAL bits in the howto byte.
 117  */
 118                 testb $KEYBOARD_BIT, MEM_BIOS_KEYBOARD # keyboard present?
 119                 jnz keyb                        # yes, so skip
 120                 orl $(RB_MULTIPLE | RB_SERIAL), (%bx) # enable serial console
 121 keyb:
 122 #endif
 123 /*
 124  * Turn on the A20 address line
 125  */
 126                 callw seta20                    # Turn A20 on
 127 /*
 128  * Relocate the loader and BTX using a very lazy protected mode
 129  */
 130                 movw $relocate_msg, %si         # Display the
 131                 callw putstr                    #  relocation message
 132                 movl end+AOUT_ENTRY, %edi       # %edi is the destination
 133                 movl $(end+AOUT_HEADER), %esi   # %esi is
 134                                                 #  the start of the text
 135                                                 #  segment
 136                 movl end+AOUT_TEXT, %ecx        # %ecx = length of the text
 137                                                 #  segment
 138                 lgdt gdtdesc                    # setup our own gdt
 139                 cli                             # turn off interrupts
 140                 movl %cr0, %eax                 # Turn on
 141                 orb $0x1, %al                   #  protected
 142                 movl %eax, %cr0                 #  mode
 143                 ljmp $SEL_SCODE,$pm_start       # long jump to clear the
 144                                                 #  instruction pre-fetch queue
 145                 .code32
 146 pm_start:       movw $SEL_SDATA, %ax            # Initialize
 147                 movw %ax, %ds                   #  %ds and
 148                 movw %ax, %es                   #  %es to a flat selector
 149                 rep                             # Relocate the
 150                 movsb                           #  text segment
 151                 addl $(MEM_PAGE_SIZE - 1), %edi # pad %edi out to a new page
 152                 andl $~(MEM_PAGE_SIZE - 1), %edi #  for the data segment
 153                 movl end+AOUT_DATA, %ecx        # size of the data segment
 154                 rep                             # Relocate the
 155                 movsb                           #  data segment
 156                 movl end+AOUT_BSS, %ecx         # size of the bss
 157                 xorl %eax, %eax                 # zero %eax
 158                 addb $3, %cl                    # round %ecx up to
 159                 shrl $2, %ecx                   #  a multiple of 4
 160                 rep                             # zero the
 161                 stosl                           #  bss
 162                 movl end+AOUT_ENTRY, %esi       # %esi -> relocated loader
 163                 addl $MEM_BTX_OFFSET, %esi      # %esi -> BTX in the loader
 164                 movl $MEM_BTX_ADDRESS, %edi     # %edi -> where BTX needs to go
 165                 movzwl 0xa(%esi), %ecx          # %ecx -> length of BTX
 166                 rep                             # Relocate
 167                 movsb                           #  BTX
 168                 ljmp $SEL_SCODE16,$pm_16        # Jump to 16-bit PM
 169                 .code16
 170 pm_16:          movw $SEL_RDATA, %ax            # Initialize
 171                 movw %ax, %ds                   #  %ds and
 172                 movw %ax, %es                   #  %es to a real mode selector
 173                 movl %cr0, %eax                 # Turn off
 174                 andb $~0x1, %al                 #  protected
 175                 movl %eax, %cr0                 #  mode
 176                 ljmp $0,$pm_end                 # Long jump to clear the
 177                                                 #  instruction pre-fetch queue
 178 pm_end:         sti                             # Turn interrupts back on now
 179 /*
 180  * Copy the BTX client to MEM_BTX_CLIENT
 181  */
 182                 xorw %ax, %ax                   # zero %ax and set
 183                 movw %ax, %ds                   #  %ds and %es
 184                 movw %ax, %es                   #  to segment 0
 185                 movw $MEM_BTX_CLIENT, %di       # Prepare to relocate
 186                 movw $btx_client, %si           #  the simple btx client
 187                 movw $(btx_client_end-btx_client), %cx # length of btx client
 188                 rep                             # Relocate the
 189                 movsb                           #  simple BTX client
 190 /*
 191  * Copy the boot[12] args to where the BTX client can see them
 192  */
 193                 movw $MEM_ARG, %si              # where the args are at now
 194                 movw $MEM_ARG_BTX, %di          # where the args are moving to
 195                 movw $(MEM_ARG_SIZE/4), %cx     # size of the arguments in longs
 196                 rep                             # Relocate
 197                 movsl                           #  the words
 198 /*
 199  * Save the entry point so the client can get to it later on
 200  */
 201                 movl end+AOUT_ENTRY, %eax       # load the entry point
 202                 stosl                           # add it to the end of the
 203                                                 #  arguments
 204 /*
 205  * Now we just start up BTX and let it do the rest
 206  */
 207                 movw $jump_message, %si         # Display the
 208                 callw putstr                    #  jump message
 209                 ljmp $0,$MEM_BTX_ENTRY          # Jump to the BTX entry point
 210
 211 /*
 212  * Display a null-terminated string
 213  */
 214 putstr:         lodsb                           # load %al from %ds:(%si)
 215                 testb %al,%al                   # stop at null
 216                 jnz putc                        # if the char != null, output it
 217                 retw                            # return when null is hit
 218 putc:           movw $0x7,%bx                   # attribute for output
 219                 movb $0xe,%ah                   # BIOS: put_char
 220                 int $0x10                       # call BIOS, print char in %al
 221                 jmp putstr                      # keep looping
 222
 223 /*
 224  * Enable A20. Put an upper limit on the amount of time we wait for the
 225  * keyboard controller to get ready (65K x ISA access time). If
 226  * we wait more than that amount, the hardware is probably
 227  * legacy-free and simply doesn't have a keyboard controller.
 228  * Thus, the A20 line is already enabled.
 229  */
 230 seta20:         cli                             # Disable interrupts
 231                 xor %cx,%cx                     # Clear
 232 seta20.1:       inc %cx                         # Increment, overflow?
 233                 jz seta20.3                     # Yes
 234                 inb $0x64,%al                   # Get status
 235                 testb $0x2,%al                  # Busy?
 236                 jnz seta20.1                    # Yes
 237                 movb $0xd1,%al                  # Command: Write
 238                 outb %al,$0x64                  #  output port
 239 seta20.2:       inb $0x64,%al                   # Get status
 240                 testb $0x2,%al                  # Busy?
 241                 jnz seta20.2                    # Yes
 242                 movb $0xdf,%al                  # Enable
 243                 outb %al,$0x60                  #  A20
 244 seta20.3:       sti                             # Enable interrupts
 245                 retw                            # To caller
 246
 247 /*
 248  * BTX client to start btxldr
 249  */
 250                 .code32
 251 btx_client:     movl $(MEM_ARG_BTX-MEM_BTX_CLIENT+MEM_ARG_SIZE-4), %esi
 252                                                 # %ds:(%esi) -> end
 253                                                 #  of boot[12] args
 254                 movl $(MEM_ARG_SIZE/4), %ecx    # Number of words to push
 255                 std                             # Go backwards
 256 push_arg:       lodsl                           # Read argument
 257                 pushl %eax                      # Push it onto the stack
 258                 loop push_arg                   # Push all of the arguments
 259                 cld                             # In case anyone depends on this
 260                 pushl MEM_ARG_BTX-MEM_BTX_CLIENT+MEM_ARG_SIZE # Entry point of
 261                                                 #  the loader
 262                 pushl %eax                      # Emulate a near call
 263                 movl $0x1, %eax                 # 'exec' system call
 264                 int $INT_SYS                    # BTX system call
 265 btx_client_end:
 266                 .code16
 267
 268                 .p2align 4
 269 /*
 270  * Global descriptor table.
 271  */
 272 gdt:            .word 0x0,0x0,0x0,0x0           # Null entry
 273                 .word 0xffff,0x0,0x9200,0xcf    # SEL_SDATA
 274                 .word 0xffff,0x0,0x9200,0x0     # SEL_RDATA
 275                 .word 0xffff,0x0,0x9a00,0xcf    # SEL_SCODE (32-bit)
 276                 .word 0xffff,0x0,0x9a00,0x8f    # SEL_SCODE16 (16-bit)
 277 gdt.1:
 278 /*
 279  * Pseudo-descriptors.
 280  */
 281 gdtdesc:        .word gdt.1-gdt-1               # Limit
 282                 .long gdt                       # Base
 283
 284 welcome_msg:    .asciz  "PXE Loader 1.00\r\n\n"
 285 bootinfo_msg:   .asciz  "Building the boot loader arguments\r\n"
 286 relocate_msg:   .asciz  "Relocating the loader and the BTX\r\n"
 287 jump_message:   .asciz  "Starting the BTX loader\r\n"
 288
 289                 .p2align 4
 290 end: