sys/boot/ia64/efi/ldscript.ia64

   1 /* $FreeBSD$ */
   2 OUTPUT_FORMAT("elf64-ia64-freebsd", "elf64-ia64-freebsd", "elf64-ia64-freebsd")
   3 OUTPUT_ARCH(ia64)
   4 ENTRY(_start_plabel)
   5 SECTIONS
   6 {
   7   /* Read-only sections, merged into text segment: */
   8   . = 0;
   9   ImageBase = .;
  10   . = SIZEOF_HEADERS;
  11   . = ALIGN(4096);
  12   .text         : {
  13     *(.text .stub .text.* .gnu.linkonce.t.*)
  14     /* .gnu.warning sections are handled specially by elf32.em. */
  15     *(.gnu.warning)
  16     *(.plt)
  17   } =0x00300000010070000002000001000400
  18   . = ALIGN(4096);
  19   __start_set_Xcommand_set = .;
  20   set_Xcommand_set      : { *(set_Xcommand_set) }
  21   __stop_set_Xcommand_set = .;
  22   .data         : {
  23     *(.rodata .rodata.* .gnu.linkonce.r.*)
  24     *(.rodata1)
  25     *(.sdata2 .sdata2.* .gnu.linkonce.s2.*)
  26     *(.sbss2 .sbss2.* .gnu.linkonce.sb2.*)
  27     *(.opd)
  28     *(.data .data.* .gnu.linkonce.d.*)
  29     *(.data1)
  30     *(.plabel)
  31     *(.dynbss)
  32     *(.bss .bss.* .gnu.linkonce.b.*)
  33     *(COMMON)
  34   }
  35   .IA_64.unwind_info    : { *(.IA_64.unwind_info* .gnu.linkonce.ia64unwi.*) }
  36   .IA_64.unwind : { *(.IA_64.unwind* .gnu.linkonce.ia64unw.*) }
  37   . = ALIGN(4096);
  38   __gp = .;
  39   .sdata        : {
  40     *(.got.plt .got)
  41     *(.IA_64.pltoff)
  42     *(.sdata .sdata.* .gnu.linkonce.s.*)
  43     *(dynsbss)
  44     *(.sbss .sbss.* .gnu.linkonce.sb.*)
  45     *(.scommon)
  46   }
  47   . = ALIGN(4096);
  48   .dynamic      : { *(.dynamic) }
  49   . = ALIGN(4096);
  50   .rela.dyn     : {
  51     *(.rela.text .rela.text.* .rela.gnu.linkonce.t.*)
  52     *(.rela.rodata .rela.rodata.* .rela.gnu.linkonce.r.*)
  53     *(.rela.data .rela.data.* .rela.gnu.linkonce.d.*)
  54     *(.rela.got)
  55     *(.rela.sdata .rela.sdata.* .rela.gnu.linkonce.s.*)
  56     *(.rela.sbss .rela.sbss.* .rela.gnu.linkonce.sb.*)
  57     *(.rela.sdata2 .rela.sdata2.* .rela.gnu.linkonce.s2.*)
  58     *(.rela.sbss2 .rela.sbss2.* .rela.gnu.linkonce.sb2.*)
  59     *(.rela.bss .rela.bss.* .rela.gnu.linkonce.b.*)
  60     *(.rela.plt)
  61     *(.rela.IA_64.pltoff)
  62     *(.relaset_*)
  63     *(.rela.dyn .rela.dyn.*)
  64   }
  65   . = ALIGN(4096);
  66   .reloc        : { *(.reloc) }
  67   . = ALIGN(4096);
  68   .hash         : { *(.hash) }
  69   . = ALIGN(4096);
  70   .dynsym       : { *(.dynsym) }
  71   . = ALIGN(4096);
  72   .dynstr       : { *(.dynstr) }
  73 }