sys/compat/linux/stats_timing.d

   1 #!/usr/sbin/dtrace -qs
   2
   3 /*-
   4  * Copyright (c) 2008-2012 Alexander Leidinger <netchild@FreeBSD.org>
   5  * All rights reserved.
   6  *
   7  * Redistribution and use in source and binary forms, with or without
   8  * modification, are permitted provided that the following conditions
   9  * are met:
  10  * 1. Redistributions of source code must retain the above copyright
  11  *    notice, this list of conditions and the following disclaimer
  12  *    in this position and unchanged.
  13  * 2. Redistributions in binary form must reproduce the above copyright
  14  *    notice, this list of conditions and the following disclaimer in the
  15  *    documentation and/or other materials provided with the distribution.
  16  *
  17  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
  18  * IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
  19  * OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
  20  * IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
  21  * INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
  22  * NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  23  * DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  24  * THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  25  * (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
  26  * THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  27  *
  28  * $FreeBSD$
  29  */
  30
  31 /**
  32  * Some statistics (all per provider):
  33  *  - number of calls to a function per executable binary (not per PID!)
  34  *    - allows to see where an optimization would be beneficial for a given
  35  *      application
  36  *  - graph of CPU time spend in functions per executable binary
  37  *    - together with the number of calls to this function this allows
  38  *      to determine if a kernel optimization would be beneficial / is
  39  *      possible for a given application
  40  *  - graph of longest running (CPU-time!) function in total
  41  *    - may help finding problem cases in the kernel code
  42  * - timing statistics for the emul_lock
  43  * - graph of longest held (CPU-time!) locks
  44  */
  45
  46 #pragma D option dynvarsize=32m
  47
  48 linuxulator*:::entry
  49 {
  50         self->time[probefunc] = vtimestamp;
  51         @calls[probeprov, execname, probefunc] = count();
  52 }
  53
  54 linuxulator*:::return
  55 /self->time[probefunc] != 0/
  56 {
  57         this->timediff = self->time[probefunc] - vtimestamp;
  58
  59         @stats[probeprov, execname, probefunc] = quantize(this->timediff);
  60         @longest[probeprov, probefunc] = max(this->timediff);
  61
  62         self->time[probefunc] = 0;
  63 }
  64
  65 linuxulator*:::locked
  66 {
  67         self->lock[arg0] = vtimestamp;
  68 }
  69
  70 linuxulator*:::unlock
  71 /self->lock[arg0] != 0/
  72 {
  73         this->timediff = self->lock[arg0] - vtimestamp;
  74
  75         @lockstats[probefunc] = quantize(this->timediff);
  76         @longlock[probefunc] = max(this->timediff);
  77
  78         self->lock[arg0] = 0;
  79 }
  80
  81 END
  82 {
  83         printf("Number of calls per provider/application/kernel function:");
  84         printa(@calls);
  85         printf("CPU-timing statistics per provider/application/kernel function (in ns):");
  86         printa(@stats);
  87         printf("Longest running (CPU-time!) functions per provider (in ns):");
  88         printa(@longest);
  89         printf("Lock CPU-timing statistics:");
  90         printa(@lockstats);
  91         printf("Longest running (CPU-time!) locks:");
  92         printa(@longlock);
  93 }
  94