usr.bin/ar/acplex.l

   1 %{
   2 /*-
   3  * Copyright (c) 2008 Kai Wang
   4  * All rights reserved.
   5  *
   6  * Redistribution and use in source and binary forms, with or without
   7  * modification, are permitted provided that the following conditions
   8  * are met:
   9  * 1. Redistributions of source code must retain the above copyright
  10  *    notice, this list of conditions and the following disclaimer
  11  *    in this position and unchanged.
  12  * 2. Redistributions in binary form must reproduce the above copyright
  13  *    notice, this list of conditions and the following disclaimer in the
  14  *    documentation and/or other materials provided with the distribution.
  15  *
  16  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR(S) ``AS IS'' AND ANY EXPRESS OR
  17  * IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
  18  * OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
  19  * IN NO EVENT SHALL THE AUTHOR(S) BE LIABLE FOR ANY DIRECT, INDIRECT,
  20  * INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
  21  * NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  22  * DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  23  * THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  24  * (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
  25  * THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  26  */
  27
  28 #include <sys/cdefs.h>
  29 __FBSDID("$FreeBSD$");
  30
  31 #include <err.h>
  32 #include <errno.h>
  33 #include <stdio.h>
  34 #include <string.h>
  35 #include <sysexits.h>
  36
  37 #include "y.tab.h"
  38
  39 int lineno = 1;
  40
  41 int     yylex(void);
  42
  43 #define YY_DECL int yylex(void)
  44
  45 %}
  46
  47 %option nounput
  48 %option noinput
  49 %option noyywrap
  50
  51 %%
  52
  53 ADDLIB|addlib           { return (ADDLIB); }
  54 ADDMOD|addmod           { return (ADDMOD); }
  55 CLEAR|clear             { return (CLEAR); }
  56 CREATE|create           { return (CREATE); }
  57 DELETE|delete           { return (DELETE); }
  58 DIRECTORY|directory     { return (DIRECTORY); }
  59 END|end                 { return (END); }
  60 EXTRACT|extract         { return (EXTRACT); }
  61 LIST|list               { return (LIST); }
  62 OPEN|open               { return (OPEN); }
  63 REPLACE|replace         { return (REPLACE); }
  64 VERBOSE|verbose         { return (VERBOSE); }
  65 SAVE|save               { return (SAVE); }
  66 "("                     { return (LP); }
  67 ")"                     { return (RP); }
  68 ","                     { return (COMMA); }
  69
  70 [-_A-Za-z0-9/:$.\\]+    {
  71         yylval.str = strdup(yytext);
  72         if (yylval.str == NULL)
  73                 errc(EX_SOFTWARE, errno, "strdup failed");
  74         return (FNAME);
  75 }
  76
  77 [ \t]                   /* whitespace */
  78 "*".*                   /* comment */
  79 ";".*                   /* comment */
  80 "+\n"                   { lineno++; /* '+' is line continuation char */ }
  81 "\n"                    { lineno++; return (EOL); }