lib/libc/amd64/gen/_setjmp.S

   1 /*-
   2  * Copyright (c) 1990 The Regents of the University of California.
   3  * All rights reserved.
   4  *
   5  * This code is derived from software contributed to Berkeley by
   6  * William Jolitz.
   7  *
   8  * Redistribution and use in source and binary forms, with or without
   9  * modification, are permitted provided that the following conditions
  10  * are met:
  11  * 1. Redistributions of source code must retain the above copyright
  12  *    notice, this list of conditions and the following disclaimer.
  13  * 2. Redistributions in binary form must reproduce the above copyright
  14  *    notice, this list of conditions and the following disclaimer in the
  15  *    documentation and/or other materials provided with the distribution.
  16  * 4. Neither the name of the University nor the names of its contributors
  17  *    may be used to endorse or promote products derived from this software
  18  *    without specific prior written permission.
  19  *
  20  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  21  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  22  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  23  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  24  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  25  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  26  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  27  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  28  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  29  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  30  * SUCH DAMAGE.
  31  */
  32
  33 #if defined(LIBC_SCCS) && !defined(lint)
  34         .asciz "@(#)_setjmp.s   5.1 (Berkeley) 4/23/90"
  35 #endif /* LIBC_SCCS and not lint */
  36 #include <machine/asm.h>
  37 __FBSDID("$FreeBSD$");
  38
  39 /*
  40  * C library -- _setjmp, _longjmp
  41  *
  42  *      _longjmp(a,v)
  43  * will generate a "return(v)" from the last call to
  44  *      _setjmp(a)
  45  * by restoring registers from the environment 'a'.
  46  * The previous signal state is NOT restored.
  47  */
  48
  49 ENTRY(_setjmp)
  50         movq    %rdi,%rax
  51         movq    0(%rsp),%rdx            /* retval */
  52         movq    %rdx, 0(%rax)           /* 0; retval */
  53         movq    %rbx, 8(%rax)           /* 1; rbx */
  54         movq    %rsp,16(%rax)           /* 2; rsp */
  55         movq    %rbp,24(%rax)           /* 3; rbp */
  56         movq    %r12,32(%rax)           /* 4; r12 */
  57         movq    %r13,40(%rax)           /* 5; r13 */
  58         movq    %r14,48(%rax)           /* 6; r14 */
  59         movq    %r15,56(%rax)           /* 7; r15 */
  60         fnstcw  64(%rax)                /* 8; fpu cw */
  61         xorq    %rax,%rax
  62         ret
  63 END(_setjmp)
  64
  65         .weak   CNAME(_longjmp)
  66         .set    CNAME(_longjmp),CNAME(___longjmp)
  67 ENTRY(___longjmp)
  68         movq    %rdi,%rdx
  69         movq    %rsi,%rax               /* retval */
  70         movq    0(%rdx),%rcx
  71         movq    8(%rdx),%rbx
  72         movq    16(%rdx),%rsp
  73         movq    24(%rdx),%rbp
  74         movq    32(%rdx),%r12
  75         movq    40(%rdx),%r13
  76         movq    48(%rdx),%r14
  77         movq    56(%rdx),%r15
  78         fninit
  79         fldcw   64(%rdx)
  80         testq   %rax,%rax
  81         jnz     1f
  82         incq    %rax
  83 1:      movq    %rcx,0(%rsp)
  84         ret
  85 END(___longjmp)