sys/sparc64/sparc64/locore.S

   1 /*-
   2  * Copyright (c) 2001 Jake Burkholder.
   3  * All rights reserved.
   4  *
   5  * Redistribution and use in source and binary forms, with or without
   6  * modification, are permitted provided that the following conditions
   7  * are met:
   8  * 1. Redistributions of source code must retain the above copyright
   9  *    notice, this list of conditions and the following disclaimer.
  10  * 2. Redistributions in binary form must reproduce the above copyright
  11  *    notice, this list of conditions and the following disclaimer in the
  12  *    documentation and/or other materials provided with the distribution.
  13  *
  14  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR AND CONTRIBUTORS ``AS IS'' AND
  15  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  16  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  17  * ARE DISCLAIMED.  IN NO EVENT SHALL THE AUTHOR OR CONTRIBUTORS BE LIABLE
  18  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  19  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  20  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  21  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  22  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  23  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  24  * SUCH DAMAGE.
  25  */
  26
  27 #include <machine/asm.h>
  28 __FBSDID("$FreeBSD$");
  29
  30 #include <machine/asi.h>
  31 #include <machine/asmacros.h>
  32 #include <machine/pstate.h>
  33
  34 #include "assym.s"
  35
  36         .register %g2,#ignore
  37
  38         .globl  kernbase
  39         .set    kernbase, KERNBASE
  40
  41 /*
  42  * void _start(caddr_t metadata, u_long o1, u_long o2, u_long o3,
  43  *     u_long ofw_vec)
  44  */
  45 ENTRY(btext)
  46 ENTRY(_start)
  47         /*
  48          * Initialize misc. state to known values: interrupts disabled, normal
  49          * globals, windows flushed (cr = 0, cs = nwindows - 1), no clean
  50          * windows, pil 0, and floating point disabled.
  51          */
  52         wrpr    %g0, PSTATE_NORMAL, %pstate
  53         flushw
  54         wrpr    %g0, 0, %cleanwin
  55         wrpr    %g0, 0, %pil
  56         wr      %g0, 0, %fprs
  57
  58         /*
  59          * Get onto our per-CPU panic stack, which precedes the struct pcpu in
  60          * the per-CPU page.
  61          */
  62         SET(pcpu0 + (PCPU_PAGES * PAGE_SIZE) - PC_SIZEOF, %l1, %l0)
  63         sub     %l0, SPOFF + CCFSZ, %sp
  64
  65         /*
  66          * Enable interrupts.
  67          */
  68         wrpr    %g0, PSTATE_KERNEL, %pstate
  69
  70         /*
  71          * Do initial bootstrap to setup pmap and thread0.
  72          */
  73         call    sparc64_init
  74          nop
  75
  76         /*
  77          * Get onto thread0's kstack.
  78          */
  79         sub     PCB_REG, SPOFF + CCFSZ, %sp
  80
  81         /*
  82          * And away we go.  This doesn't return.
  83          */
  84         call    mi_startup
  85          nop
  86         sir
  87         ! NOTREACHED
  88 END(_start)
  89
  90 /*
  91  * void cpu_setregs(struct pcpu *pc)
  92  */
  93 ENTRY(cpu_setregs)
  94         ldx     [%o0 + PC_CURPCB], %o1
  95
  96         /*
  97          * Disable interrupts, normal globals.
  98          */
  99         wrpr    %g0, PSTATE_NORMAL, %pstate
 100
 101         /*
 102          * Normal %g6 points to the current thread's PCB, and %g7 points to
 103          * the per-CPU data structure.
 104          */
 105         mov     %o1, PCB_REG
 106         mov     %o0, PCPU_REG
 107
 108         /*
 109          * Switch to alternate globals.
 110          */
 111         wrpr    %g0, PSTATE_ALT, %pstate
 112
 113         /*
 114          * Alternate %g5 points to a per-CPU panic stack, %g6 points to the
 115          * current thread's PCB, and %g7 points to the per-CPU data structure.
 116          */
 117         mov     %o0, ASP_REG
 118         mov     %o1, PCB_REG
 119         mov     %o0, PCPU_REG
 120
 121         /*
 122          * Switch to interrupt globals.
 123          */
 124         wrpr    %g0, PSTATE_INTR, %pstate
 125
 126         /*
 127          * Interrupt %g7 points to the per-CPU data structure.
 128          */
 129         mov     %o0, PCPU_REG
 130
 131         /*
 132          * Switch to normal globals again.
 133          */
 134         wrpr    %g0, PSTATE_NORMAL, %pstate
 135
 136         /*
 137          * Force trap level 1 and take over the trap table.
 138          */
 139         SET(tl0_base, %o2, %o1)
 140         wrpr    %g0, 1, %tl
 141         wrpr    %o1, 0, %tba
 142
 143         /*
 144          * Re-enable interrupts.
 145          */
 146         wrpr    %g0, PSTATE_KERNEL, %pstate
 147
 148         retl
 149          nop
 150 END(cpu_setregs)